clean: remove CMake from project

CMakeLists.txt

-cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
-
-project(batsched CXX)
-
-set(CMAKE_BUILD_TYPE Debug)
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra")
-
-set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
-
-# Options
-option(enable_warnings "Enable compilation warnings" ON)
-option(treat_warnings_as_errors "Treat compilation warnings as compilation errors" OFF)
-option(do_coverage "Compile in coverage mode" OFF)
-
-# Build type
-# Set a default build type if none was specified
-if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
-  message(STATUS "Setting build type to 'Debug' as none was specified.")
-  set(CMAKE_BUILD_TYPE Debug CACHE STRING "Choose the type of build." FORCE)
-  # Set the possible values of build type for cmake-gui
-  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
-    "MinSizeRel" "RelWithDebInfo")
-endif()
-
-# Let's enable C++11
-set(CMAKE_CXX_STANDARD 11)
-set(CMAKE_CXX_STANDARD_REQUIRED ON)
-
-# Coverage
-if (do_coverage)
-    set(coverage_cxxflags "-g -O0 -fprofile-arcs -ftest-coverage")
-    set(coverage_ldflags "-lgcov --coverage")
-
-    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${coverage_cxxflags}")
-    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${coverage_ldflags}")
-endif()
-
-# Dependencies
-## Boost
-find_package(Boost 1.48 REQUIRED COMPONENTS regex locale)
-include_directories(${Boost_INCLUDE_DIR})
-
-## Intervalset
-find_package(intervalset REQUIRED)
-include_directories(${INTERVALSET_INCLUDE_DIR})
-
-## loguru
-find_package(loguru REQUIRED)
-include_directories(${LOGURU_INCLUDE_DIR})
-
-## pthread (for loguru)
-set(THREADS_PREFER_PTHREAD_FLAG ON)
-find_package(Threads REQUIRED)
-
-## GMP
-find_package(GMP REQUIRED)
-include_directories(${GMP_INCLUDE_DIR})
-
-## RapidJSON
-find_package(rapidjson REQUIRED)
-include_directories(${RAPIDJSON_INCLUDE_DIRS})
-
-## Redox dependency
-find_package(redox REQUIRED)
-include_directories(${REDOX_INCLUDE_DIR})
-
-## Redox sub dependencies
-find_package(hiredis REQUIRED)
-include_directories(${HIREDIS_INCLUDE_DIRS})
-
-find_package(libev REQUIRED)
-include_directories(${LIBEV_INCLUDE_DIRS})
-
-# ZeroMQ dependency
-find_package(ZMQ REQUIRED)
-include_directories(${ZMQ_INCLUDE_DIRS})
-
-file(GLOB batsched_SRC
-    "src/*.hpp"
-    "src/*.cpp"
-    "src/algo/*.hpp"
-    "src/algo/*.cpp")
-
-add_executable(batsched ${batsched_SRC})
-
-target_link_libraries(batsched ${GMP_LIBRARIES}
-                      ${Boost_REGEX_LIBRARY_DEBUG}
-                      ${Boost_LOCALE_LIBRARY_DEBUG}
-                      ${INTERVALSET_LIBRARY}
-                      ${LOGURU_LIBRARIES}
-                      Threads::Threads
-                      ${CMAKE_DL_LIBS}
-                      ${REDOX_LIBRARY}
-                      ${LIBEV_LIBRARY}
-                      ${HIREDIS_LIBRARY}
-                      ${ZMQ_LIBRARIES})
-
-target_link_libraries(batsched boost_program_options)
-
-# Installation
-install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/batsched
-        DESTINATION bin)
-
-# Let's enable warnings if needed
-if (enable_warnings)
-    set(warning_flags " -Wall -Wextra")
-
-    if (treat_warnings_as_errors)
-        set(warning_flags "${warning_flags} -Werror")
-    endif()
-
-    if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
-        set_property(TARGET batsched APPEND_STRING PROPERTY COMPILE_FLAGS ${warning_flags})
-    elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
-        set_property(TARGET batsched APPEND_STRING PROPERTY COMPILE_FLAGS ${warning_flags})
-    else()
-        message(WARNING "Unknown compiler. Warnings should not be enabled correctly.")
-        set_property(TARGET batsched APPEND_STRING PROPERTY COMPILE_FLAGS ${warning_flags})
-    endif()
-endif()
-
-####################
-# Batsched version #
-####################
-set(default_batsched_version "v1.4.0")
-include(GetGitRevisionDescription)
-git_describe(batsched_version)
-message(STATUS "Batsched version from git: ${batsched_version}")
-
-if(NOT((${batsched_version} STREQUAL "GIT-NOTFOUND") OR
-       (${batsched_version} STREQUAL "HEAD-HASH-NOTFOUND")))
-    add_definitions(-DBATSCHED_VERSION=${batsched_version})
-else()
-    message(WARNING "Cannot retrieve Batsched version from git. "
-                    "Using default version ${default_batsched_version}")
-    add_definitions(-DBATSCHED_VERSION=${default_batsched_version})
-endif()

cmake/Modules/FindGMP.cmake

-# Try to find the GMP librairies
-# GMP_FOUND - system has GMP lib
-# GMP_INCLUDE_DIR - the GMP include directory
-# GMP_LIBRARIES - Libraries needed to use GMP
-
-if (GMP_INCLUDE_DIR AND GMP_LIBRARIES)
-        # Already in cache, be silent
-        set(GMP_FIND_QUIETLY TRUE)
-endif (GMP_INCLUDE_DIR AND GMP_LIBRARIES)
-
-find_path(GMP_INCLUDE_DIR NAMES gmp.h )
-find_library(GMP_LIBRARIES NAMES gmp libgmp )
-find_library(GMPXX_LIBRARIES NAMES gmpxx libgmpxx )
-MESSAGE(STATUS "GMP libs: " ${GMP_LIBRARIES} " " ${GMPXX_LIBRARIES} )
-
-include(FindPackageHandleStandardArgs)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(GMP DEFAULT_MSG GMP_INCLUDE_DIR GMP_LIBRARIES)
-
-mark_as_advanced(GMP_INCLUDE_DIR GMP_LIBRARIES)

cmake/Modules/FindZMQ.cmake

-# - Try to find ZMQ
-# Once done this will define
-# ZMQ_FOUND - System has ZMQ
-# ZMQ_INCLUDE_DIRS - The ZMQ include directories
-# ZMQ_LIBRARIES - The libraries needed to use ZMQ
-# ZMQ_DEFINITIONS - Compiler switches required for using ZMQ
-
-find_path ( ZMQ_INCLUDE_DIR zmq.h )
-find_library ( ZMQ_LIBRARY NAMES zmq )
-
-set ( ZMQ_LIBRARIES ${ZMQ_LIBRARY} )
-set ( ZMQ_INCLUDE_DIRS ${ZMQ_INCLUDE_DIR} )
-
-include ( FindPackageHandleStandardArgs )
-# handle the QUIETLY and REQUIRED arguments and set ZMQ_FOUND to TRUE
-# if all listed variables are TRUE
-find_package_handle_standard_args ( ZMQ DEFAULT_MSG ZMQ_LIBRARY ZMQ_INCLUDE_DIR )

cmake/Modules/Findhiredis.cmake

-# File got from redox repo, https://github.com/hmartiro/redox.
-# Try to find hiredis
-# Once done, this will define
-#
-# HIREDIS_FOUND        - system has hiredis
-# HIREDIS_INCLUDE_DIRS - hiredis include directories
-# HIREDIS_LIBRARIES    - libraries need to use hiredis
-
-if(HIREDIS_INCLUDE_DIRS AND HIREDIS_LIBRARIES)
-  set(HIREDIS_FIND_QUIETLY TRUE)
-else()
-  find_path(
-    HIREDIS_INCLUDE_DIR
-    NAMES hiredis/hiredis.h
-    HINTS ${HIREDIS_ROOT_DIR}
-    PATH_SUFFIXES include)
-
-  find_library(
-    HIREDIS_LIBRARY
-    NAMES hiredis
-    HINTS ${HIREDIS_ROOT_DIR}
-    PATH_SUFFIXES ${CMAKE_INSTALL_LIBDIR})
-
-  set(HIREDIS_INCLUDE_DIRS ${HIREDIS_INCLUDE_DIR})
-  set(HIREDIS_LIBRARIES ${HIREDIS_LIBRARY})
-
-  include (FindPackageHandleStandardArgs)
-  find_package_handle_standard_args(
-    hiredis DEFAULT_MSG HIREDIS_LIBRARY HIREDIS_INCLUDE_DIR)
-
-  mark_as_advanced(HIREDIS_LIBRARY HIREDIS_INCLUDE_DIR)
-endif()

cmake/Modules/Findintervalset.cmake

-# Find the intervalset library (https://framagit.org/batsim/intervalset)
-#
-# Sets the usual variables expected for find_package scripts:
-#
-# INTERVALSET_INCLUDE_DIR - header location
-# INTERVALSET_LIBRARIES - library to link against
-# INTERVALSET_FOUND - true if intervalset was found.
-
-find_path(INTERVALSET_INCLUDE_DIR intervalset.hpp)
-find_library(INTERVALSET_LIBRARY intervalset)
-
-# Support the REQUIRED and QUIET arguments, and set INTERVALSET_FOUND if found.
-include (FindPackageHandleStandardArgs)
-find_package_handle_standard_args(intervalset DEFAULT_MSG INTERVALSET_LIBRARY
-                                  INTERVALSET_INCLUDE_DIR)
-
-mark_as_advanced(INTERVALSET_LIBRARY INTERVALSET_INCLUDE_DIR)

cmake/Modules/Findlibev.cmake

-# File got from redox repo, https://github.com/hmartiro/redox.
-# Try to find libev
-# Once done, this will define
-#
-# LIBEV_FOUND        - system has libev
-# LIBEV_INCLUDE_DIRS - libev include directories
-# LIBEV_LIBRARIES    - libraries needed to use libev
-
-if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
-  set(LIBEV_FIND_QUIETLY TRUE)
-else()
-  find_path(
-    LIBEV_INCLUDE_DIR
-    NAMES ev.h
-    HINTS ${LIBEV_ROOT_DIR}
-    PATH_SUFFIXES include)
-
-  find_library(
-    LIBEV_LIBRARY
-    NAME ev
-    HINTS ${LIBEV_ROOT_DIR}
-    PATH_SUFFIXES ${CMAKE_INSTALL_LIBDIR})
-
-  set(LIBEV_INCLUDE_DIRS ${LIBEV_INCLUDE_DIR})
-  set(LIBEV_LIBRARIES ${LIBEV_LIBRARY})
-
-  include(FindPackageHandleStandardArgs)
-  find_package_handle_standard_args(
-    libev DEFAULT_MSG LIBEV_LIBRARY LIBEV_INCLUDE_DIR)
-
-  mark_as_advanced(LIBEV_LIBRARY LIBEV_INCLUDE_DIR)
-endif()

cmake/Modules/Findloguru.cmake

-# Find the loguru library (https://github.com/emilk/loguru)
-#
-# Sets the usual variables expected for find_package scripts:
-#
-# LOGURU_INCLUDE_DIR - header location
-# LOGURU_LIBRARIES - libraries needed to use loguru
-# LOGURU_FOUND - true if loguru was found.
-
-find_path(LOGURU_INCLUDE_DIR loguru.hpp)
-find_library(LOGURU_LIBRARIES NAMES loguru libloguru)
-
-# Support the REQUIRED and QUIET arguments, and set LOGURU_FOUND if found.
-include (FindPackageHandleStandardArgs)
-find_package_handle_standard_args(loguru DEFAULT_MSG LOGURU_INCLUDE_DIR LOGURU_LIBRARIES)
-
-mark_as_advanced(LOGURU_INCLUDE_DIR LOGURU_LIBRARIES)

cmake/Modules/Findrapidjson.cmake

-# Copyright (c) 2011 Milo Yip (miloyip@gmail.com)
-# Copyright (c) 2013 Rafal Jeczalik (rjeczalik@gmail.com)
-# Distributed under the MIT License (see license.txt file)
-
-# -----------------------------------------------------------------------------------
-#
-# Finds the rapidjson library
-#
-# -----------------------------------------------------------------------------------
-#
-# Variables used by this module, they can change the default behaviour.
-# Those variables need to be either set before calling find_package
-# or exported as environment variables before running CMake:
-#
-# RAPIDJSON_INCLUDEDIR - Set custom include path, useful when rapidjson headers are
-#                        outside system paths
-# RAPIDJSON_USE_SSE2   - Configure rapidjson to take advantage of SSE2 capabilities
-# RAPIDJSON_USE_SSE42  - Configure rapidjson to take advantage of SSE4.2 capabilities
-#
-# -----------------------------------------------------------------------------------
-#
-# Variables defined by this module:
-#
-# RAPIDJSON_FOUND        - True if rapidjson was found
-# RAPIDJSON_INCLUDE_DIRS - Path to rapidjson include directory
-# RAPIDJSON_CXX_FLAGS    - Extra C++ flags required for compilation with rapidjson
-#
-# -----------------------------------------------------------------------------------
-#
-# Example usage:
-#
-#  set(RAPIDJSON_USE_SSE2 ON)
-#  set(RAPIDJSON_INCLUDEDIR "/opt/github.com/rjeczalik/rapidjson/include")
-#
-#  find_package(rapidjson REQUIRED)
-#
-#  include_directories("${RAPIDJSON_INCLUDE_DIRS}")
-#  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${RAPIDJSON_CXX_FLAGS}")
-#  add_executable(foo foo.cc)
-#
-# -----------------------------------------------------------------------------------
-
-foreach(opt RAPIDJSON_INCLUDEDIR RAPIDJSON_USE_SSE2 RAPIDJSON_USE_SSE42)
-  if(${opt} AND DEFINED ENV{${opt}} AND NOT ${opt} STREQUAL "$ENV{${opt}}")
-    message(WARNING "Conflicting ${opt} values: ignoring environment variable and using CMake cache entry.")
-  elseif(DEFINED ENV{${opt}} AND NOT ${opt})
-    set(${opt} "$ENV{${opt}}")
-  endif()
-endforeach()
-
-find_path(
-  RAPIDJSON_INCLUDE_DIRS
-  NAMES rapidjson/rapidjson.h
-  PATHS ${RAPIDJSON_INCLUDEDIR}
-  DOC "Include directory for the rapidjson library."
-)
-
-mark_as_advanced(RAPIDJSON_INCLUDE_DIRS)
-
-if(RAPIDJSON_INCLUDE_DIRS)
-  set(RAPIDJSON_FOUND TRUE)
-endif()
-
-mark_as_advanced(RAPIDJSON_FOUND)
-
-if(RAPIDJSON_USE_SSE42)
-  set(RAPIDJSON_CXX_FLAGS "-DRAPIDJSON_SSE42")
-  if(MSVC)
-    set(RAPIDJSON_CXX_FLAGS "${RAPIDJSON_CXX_FLAGS} /arch:SSE4.2")
-  else()
-    set(RAPIDJSON_CXX_FLAGS "${RAPIDJSON_CXX_FLAGS} -msse4.2")
-  endif()
-else()
-  if(RAPIDJSON_USE_SSE2)
-    set(RAPIDJSON_CXX_FLAGS "-DRAPIDJSON_SSE2")
-    if(MSVC)
-      set(RAPIDJSON_CXX_FLAGS "${RAPIDJSON_CXX_FLAGS} /arch:SSE2")
-    else()
-      set(RAPIDJSON_CXX_FLAGS "${RAPIDJSON_CXX_FLAGS} -msse2")
-    endif()
-  endif()
-endif()
-
-mark_as_advanced(RAPIDJSON_CXX_FLAGS)
-
-if(RAPIDJSON_FOUND)
-  if(NOT rapidjson_FIND_QUIETLY)
-    message(STATUS "Found rapidjson header files in ${RAPIDJSON_INCLUDE_DIRS}")
-    if(DEFINED RAPIDJSON_CXX_FLAGS)
-      message(STATUS "Found rapidjson C++ extra compilation flags: ${RAPIDJSON_CXX_FLAGS}")
-    endif()
-  endif()
-elseif(rapidjson_FIND_REQUIRED)
-    message(FATAL_ERROR "Could not find rapidjson")
-else()
-  message(STATUS "Optional package rapidjson was not found")
-endif()

cmake/Modules/Findredox.cmake

-# Try fo find Redox.
-# Once done, this will define:
-#   REDOX_FOUND
-#   REDOX_INCLUDE_DIRS
-#   REDOX_LIBRARIES
-
-find_path(
-    REDOX_INCLUDE_DIR
-    NAMES redox.hpp
-    HINTS ${REDOX_ROOT_DIR})
-
-find_library(
-    REDOX_LIBRARY
-    NAMES redox
-    HINTS ${REDOX_ROOT_DIR}
-    PATH_SUFFIXES ${CMAKE_INSTALL_LIBDIR})
-
-set(REDOX_INCLUDE_DIRS ${REDOX_INCLUDE_DIR})
-set(REDOX_LIBRARIES ${REDOX_LIBRARY})
-
-include (FindPackageHandleStandardArgs)
-    find_package_handle_standard_args(
-    redox DEFAULT_MSG REDOX_LIBRARY REDOX_INCLUDE_DIR)
-
-mark_as_advanced(REDOX_LIBRARY REDOX_INCLUDE_DIR)

cmake/Modules/GetGitRevisionDescription.cmake

-# - Returns a version string from Git
-#
-# These functions force a re-configure on each git commit so that you can
-# trust the values of the variables in your build system.
-#
-#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
-#
-# Returns the refspec and sha hash of the current head revision
-#
-#  git_describe(<var> [<additional arguments to git describe> ...])
-#
-# Returns the results of git describe on the source tree, and adjusting
-# the output so that it tests false if an error occurs.
-#
-#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
-#
-# Returns the results of git describe --exact-match on the source tree,
-# and adjusting the output so that it tests false if there was no exact
-# matching tag.
-#
-#  git_local_changes(<var>)
-#
-# Returns either "CLEAN" or "DIRTY" with respect to uncommitted changes.
-# Uses the return code of "git diff-index --quiet HEAD --".
-# Does not regard untracked files.
-#
-# Requires CMake 2.6 or newer (uses the 'function' command)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-if(__get_git_revision_description)
-    return()
-endif()
-set(__get_git_revision_description YES)
-
-# We must run the following at "include" time, not at function call time,
-# to find the path to this module rather than the path to a calling list file
-get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
-
-function(get_git_head_revision _refspecvar _hashvar)
-    set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
-    set(GIT_DIR "${GIT_PARENT_DIR}/.git")
-    while(NOT EXISTS "${GIT_DIR}")  # .git dir not found, search parent directories
-        set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
-        get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
-        if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
-            # We have reached the root directory, we are not in git
-            set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
-            set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
-            return()
-        endif()
-        set(GIT_DIR "${GIT_PARENT_DIR}/.git")
-    endwhile()
-    # check if this is a submodule
-    if(NOT IS_DIRECTORY ${GIT_DIR})
-        file(READ ${GIT_DIR} submodule)
-        string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
-        get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
-        get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
-    endif()
-    set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
-    if(NOT EXISTS "${GIT_DATA}")
-        file(MAKE_DIRECTORY "${GIT_DATA}")
-    endif()
-
-    if(NOT EXISTS "${GIT_DIR}/HEAD")
-        return()
-    endif()
-    set(HEAD_FILE "${GIT_DATA}/HEAD")
-    configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
-
-    configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
-        "${GIT_DATA}/grabRef.cmake"
-        @ONLY)
-    include("${GIT_DATA}/grabRef.cmake")
-
-    set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
-    set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
-endfunction()
-
-function(git_describe _var)
-    if(NOT GIT_FOUND)
-        find_package(Git QUIET)
-    endif()
-    get_git_head_revision(refspec hash)
-    if(NOT GIT_FOUND)
-        set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
-        return()
-    endif()
-    if(NOT hash)
-        set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
-        return()
-    endif()
-
-    # TODO sanitize
-    #if((${ARGN}" MATCHES "&&") OR
-    #   (ARGN MATCHES "||") OR
-    #   (ARGN MATCHES "\\;"))
-    #   message("Please report the following error to the project!")
-    #   message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
-    #endif()
-
-    #message(STATUS "Arguments to execute_process: ${ARGN}")
-
-    execute_process(COMMAND
-        "${GIT_EXECUTABLE}"
-        describe
-        ${hash}
-        ${ARGN}
-        WORKING_DIRECTORY
-        "${CMAKE_CURRENT_SOURCE_DIR}"
-        RESULT_VARIABLE
-        res
-        OUTPUT_VARIABLE
-        out
-        ERROR_QUIET
-        OUTPUT_STRIP_TRAILING_WHITESPACE)
-    if(NOT res EQUAL 0)
-        set(out "${out}-${res}-NOTFOUND")
-    endif()
-
-    set(${_var} "${out}" PARENT_SCOPE)
-endfunction()
-
-function(git_get_exact_tag _var)
-    git_describe(out --exact-match ${ARGN})
-    set(${_var} "${out}" PARENT_SCOPE)
-endfunction()
-
-function(git_local_changes _var)
-    if(NOT GIT_FOUND)
-        find_package(Git QUIET)
-    endif()
-    get_git_head_revision(refspec hash)
-    if(NOT GIT_FOUND)
-        set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
-        return()
-    endif()
-    if(NOT hash)
-        set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
-        return()
-    endif()
-
-    execute_process(COMMAND
-        "${GIT_EXECUTABLE}"
-        diff-index --quiet HEAD --
-        WORKING_DIRECTORY
-        "${CMAKE_CURRENT_SOURCE_DIR}"
-        RESULT_VARIABLE
-        res
-        OUTPUT_VARIABLE
-        out
-        ERROR_QUIET
-        OUTPUT_STRIP_TRAILING_WHITESPACE)
-    if(res EQUAL 0)
-        set(${_var} "CLEAN" PARENT_SCOPE)
-    else()
-        set(${_var} "DIRTY" PARENT_SCOPE)
-    endif()
-endfunction()

cmake/Modules/GetGitRevisionDescription.cmake.in

-#
-# Internal file for GetGitRevisionDescription.cmake
-#
-# Requires CMake 2.6 or newer (uses the 'function' command)
-#
-# Original Author:
-# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
-# http://academic.cleardefinition.com
-# Iowa State University HCI Graduate Program/VRAC
-#
-# Copyright Iowa State University 2009-2010.
-# Distributed under the Boost Software License, Version 1.0.
-# (See accompanying file LICENSE_1_0.txt or copy at
-# http://www.boost.org/LICENSE_1_0.txt)
-
-set(HEAD_HASH)
-
-file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
-
-string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
-if(HEAD_CONTENTS MATCHES "ref")
-    # named branch
-    string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
-    if(EXISTS "@GIT_DIR@/${HEAD_REF}")
-        configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
-    else()
-        configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs" COPYONLY)
-        file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
-        if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
-            set(HEAD_HASH "${CMAKE_MATCH_1}")
-        endif()
-    endif()
-else()
-    # detached HEAD
-    configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
-endif()
-
-if(NOT HEAD_HASH)
-    file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
-    string(STRIP "${HEAD_HASH}" HEAD_HASH)
-endif()